/*
-----------------------------------------------------------------------------------------
Net Revenue to Units New Parameters
Created On: 5/2/2017
Created By: Carol Diem
[bookmark: _GoBack]Last Modified: 7/19/2017
Last Modified by: Carol Diem

This file calculates the distribution for FY17 using the new distribution rules. Students in the new Graduate School tuition
categories are separated out so the different distribution rules can be applied. This file can be used going forward.
-----------------------------------------------------------------------------------------*/




SET NOCOUNT ON

--Set range of complete fiscal years

Declare @StartFY as int
Set @StartFY=2017
Declare @EndFY as int
Set @EndFY=2017

--The following drop table commands are included for any temporary tables created below.
If Object_ID('tempdb..#ABB_FTE') Is not null drop table #ABB_FTE
If Object_ID('tempdb..#QuarterlyWaiverTotal') Is not null drop table #QuarterlyWaiverTotal
If Object_ID('tempdb..#GrossOpWithWaivers') Is not null drop table #GrossOpWithWaivers
If Object_ID('tempdb..#UncalibratedNetRevenue') Is not null drop table #UncalibratedNetRevenue
If Object_ID('tempdb..#NetByCampus') Is not null drop table #NetByCampus
If Object_ID('tempdb..#AddlAid') Is not null drop table #AddlAid
If Object_ID('tempdb..#CalibrationFactor') Is not null drop table #CalibrationFactor
If Object_ID('tempdb..#CalibratedNetRevenueS1') Is not null drop table #CalibratedNetRevenueS1
If Object_ID('tempdb..#CalibratedNetRevenueS2') Is not null drop table #CalibratedNetRevenueS2
If Object_ID('tempdb..#CalibratedNetRevenueS3') Is not null drop table #CalibratedNetRevenueS3
If Object_ID('tempdb..#CalibratedNetRevenueS4') Is not null drop table #CalibratedNetRevenueS4
If Object_ID('tempdb..#PharmDBothellMBA') Is not null drop table #PharmDBothellMBA
If Object_ID('tempdb..##CalibratedNetRevenue') Is not null drop table ##CalibratedNetRevenue
If Object_ID('tempdb..##CalibratedNetRevenueByTG') Is not null drop table ##CalibratedNetRevenueByTG
If Object_ID('tempdb..#RevByColl') Is not null drop table #RevByColl
If Object_ID('tempdb..#Pcnts') Is not null drop table #Pcnts
If Object_ID('tempdb..#TGbyCollege') Is not null drop table #TGbyCollege
If Object_ID('tempdb..#TGbyCollegeByFY') Is not null drop table #TGbyCollegeByFY
If Object_ID('tempdb..#PercentageSCHbyTuitionGroupByCollege') Is not null drop table #PercentageSCHbyTuitionGroupByCollege
If Object_ID('tempdb..#PercentageDegreeMajorsByCollege') Is not null drop table #PercentageDegreeMajorsByCollege
If Object_ID('tempdb..#PercentageMajorEnrollmentsByTGbyCollege') Is not null drop table #PercentageMajorEnrollmentsByTGbyCollege
If Object_ID('tempdb..##RevToCollOldParameters') Is not null drop table ##RevToCollOldParameters
If Object_ID('tempdb..##RevToCollNewParameters') Is not null drop table ##RevToCollNewParameters
If Object_ID('tempdb..#GradSchoolStdts') Is not null drop table #GradSchoolStdts
If Object_ID('tempdb..##StudentTuitionNewTC') Is not null drop table ##StudentTuitionNewTC
If Object_ID('tempdb..#RevByTGbyColl') Is not null drop table #RevByTGbyColl
/******************************************
Net Revenue Step 1: Calculate ABB FTE
*******************************************/

--The ABB_CourseSectionRegistrationsTable has the ABB FTE associated with each course registration calculated. 
--To calculate the quarterly FTE associated for each student, the ABB_FTE associated with all course registrations for a student are summed.

Select AcademicFiscalYr
      ,AcademicQtrKeyId
      ,SDBSrcSystemKey
      ,NonSummerInd
      ,SUM(ABBFTEQty) As ABB_FTE
Into #ABB_FTE
From AnalyticInteg.sec.ABB_CourseSectionRegistrations
Where ABBFTEQty>0 and AcademicFiscalYr between @StartFY and @EndFY
Group by
       AcademicFiscalYr
      ,AcademicQtrKeyId
      ,NonSummerInd
      ,SDBSrcSystemKey
 
/******************************************************
Net Revenue Step 2: Sum waivers over waiver categories
*******************************************************/

-- The ABB_StudentWaivers table has a record for every student receiving a waiver in a quarter for every waiver category in which they receive a waiver. 
----Since there can be multiple records per student, the #QtrWaivTot temp table, which removes the waiver category distinction and provides one record 
----(including the total waiver amount for each student receiving one or more waivers), is created (to simplify the process of joining tuition information with waiver information).

Select AcademicFiscalYr
      ,AcademicQtrKeyId
      ,SDBSrcSystemKey
      ,SUM(TotalOperatingFeeWaiverAmt) As OpWvr
Into #QuarterlyWaiverTotal
From AnalyticInteg.sec.ABB_StudentWaivers 
Where AcademicFiscalYr between @StartFY and @EndFY
Group By AcademicFiscalYr
        ,AcademicQtrKeyId
        ,SDBSrcSystemKey

/******************************************************************
Net Revenue Step 3: Reassign students to Grad School Tuition Tiers
*******************************************************************/

--Identify students enrolled in programs run by the Grad School who are currently paying Tier I or TierIII tuition.

Select t.AcademicFiscalYr
      ,t.AcademicQtrKeyId
      ,t.SDBSrcSystemKey
      ,t.TuitionCampus
      ,t.TuitionResidency
      ,t.TuitionResidencyName
      ,Case 
         When t.TuitionCampus=0 and t.TuitionCategory=5 and m.MajorCode in ('0_MCB_00','0_NEUBEH_00','0_N&MES_00','0_UD&PL_00','0_BMSD_00','0_IPHD_00','0_MCB_10','0_BPSD_00','0_NEURO_00') 
         Then 6 
         When t.TuitionCampus=0 and t.TuitionCategory=9 and m.MajorCode like '0_MOLE%' 
         Then 10 
       End As TCNew1
      ,Case 
         When t.TuitionCampus=0 and t.TuitionCategory=5 and m.MajorCode in ('0_MCB_00','0_NEUBEH_00','0_N&MES_00','0_UD&PL_00','0_BMSD_00','0_IPHD_00','0_MCB_10','0_BPSD_00','0_NEURO_00')
         Then 'Grad School Tier I' 
         When t.TuitionCampus=0 and t.TuitionCategory=9 and m.MajorCode like '0_MOLE%' 
         Then 'Grad School Tier III' 
       End As TCNameNew1
      ,Case 
         When t.TuitionCampus=0 and t.TuitionGroup=3 and m.MajorCode in ('0_MCB_00','0_NEUBEH_00','0_N&MES_00','0_UD&PL_00','0_BMSD_00','0_IPHD_00','0_MCB_10','0_BPSD_00','0_NEURO_00') 
         Then 4 
         When t.TuitionCampus=0 and t.TuitionGroup=7 and m.MajorCode like'0_MOLE%' 
         Then 8 
       End As TGNew1
      ,Case 
         When t.TuitionCampus=0 and t.TuitionGroup=3 and m.MajorCode in ('0_MCB_00','0_NEUBEH_00','0_N&MES_00','0_UD&PL_00','0_BMSD_00','0_IPHD_00','0_MCB_10','0_BPSD_00','0_NEURO_00') 
         Then 'Grad School Tier I' 
         When t.TuitionCampus=0 and t.TuitionGroup=7 and m.MajorCode like'0_MOLE%' 
         Then 'Grad School Tier III' 
       End As TGNameNew1
             
Into #GradSchoolStdts      
FROM AnalyticInteg.sec.ABB_StudentTuition t
Left join AnalyticInteg.sec.ABB_GraduateMajorProgramEnrollments m
  On  t.AcademicQtrKeyId=m.AcademicQtrKeyId
  And t.SDBSrcSystemKey=m.SDBSrcSystemKey
Where t.AcademicFiscalYr=2017  
  And t.NonSummerInd='Y'
  And t.TuitionCampus=0 --all tuition category/group changes are at Seattle 
  And 
   (
    (t.TuitionCategory=5 and m.MajorCode in ('0_MCB_00','0_NEUBEH_00','0_N&MES_00','0_UD&PL_00','0_BMSD_00','0_IPHD_00','0_MCB_10','0_BPSD_00','0_NEURO_00'))
     or 
    (t.TuitionCategory=9 and m.MajorCode like '0_MOLE%')
   )
 
--Make new StudentTuitionTable w new categories

Select t.AcademicFiscalYr
      ,t.AcademicQtrKeyId 
      ,t.TuitionCampus
      ,t.SDBSrcSystemKey
      ,Case When g.SDBSrcSystemKey>0 Then g.TCNew1     Else t.TuitionCategory     End As TuitionCategory
      ,Case When g.SDBSrcSystemKey>0 Then g.TCNameNew1 Else t.TuitionCategoryName End As TuitionCategoryName
      ,Case When g.SDBSrcSystemKey>0 Then g.TGNew1     Else t.TuitionGroup        End As TuitionGroup
      ,Case When g.SDBSrcSystemKey>0 Then g.TGNameNew1 Else t.TuitionGroupName    End As TuitionGroupName
      ,t.TuitionResidency
      ,t.TuitionResidencyName
      ,t.TotalOperatingFeeAmt
      ,t.OperatingFeeResidentPortion
      
Into ##StudentTuitionNewTC
From  AnalyticInteg.sec.ABB_StudentTuition t
Left Join #GradSchoolStdts g
  On  t.AcademicQtrKeyId = g.AcademicQtrKeyId 
  And t.SDBSrcSystemKey = g.SDBSrcSystemKey
Where t.AcademicFiscalYr Between @StartFY and @EndFY
  and t.NonSummerInd='Y' 
  and t.TuitionCampus=0

/*************************************************************
Net Revenue Step 4: Combine gross op fee revenue with waivers
**************************************************************/

--A left join is made from ##StudentTuitionNewTC, which has each student's tuition category information as well as the operating fee charged, to the temp table, #QuarterlyWaiverTotal. A left join is required because not every student receives a waiver.

Select st.AcademicFiscalYr
      ,st.AcademicQtrKeyId
      ,st.TuitionCampus
      ,st.TuitionGroup
      ,st.TuitionGroupName
      ,Right('0'+convert(varchar(2),TuitionGroup),2)+' - '+TuitionGroupName As TGsort 
      ,st.TuitionCategory
      ,st.TuitionCategoryName
      ,st.TuitionResidency
      ,st.TuitionResidencyName
      ,Case 
         When TuitionGroup=1 and TuitionResidency=1 Then '1. Undergraduate Resident' 
         When TuitionGroup=1 and TuitionResidency=2 Then '2. Undergraduate Nonresident' 
         When TuitionGroup>1 and TuitionResidency=1 Then '3. Grad/Prof Resident' 
         When TuitionGroup>1 and TuitionResidency=2 Then '4. Grad/Prof Nonresident' 
       End As StdtLvl -- In a number of instances, we need to break out revenue into these four groups
      ,Count(st.SDBSrcSystemKey)/3          As AnnualHeadcount --Total Student Head Count (Annualized) for the given Academic Fiscal Year, campus, category, residency combo
      ,Count(st.SDBSrcSystemKey)            As QtrHeadcount --Total Student Head Count for the given quarter, campus, category, residency combo 
      ,Sum(fte.ABB_FTE)/3                   As AnnualFTE --Total (Annualized) Student FTE for the given Academic Fiscal Year, campus, category, residency combo
      ,Sum(fte.ABB_FTE)                     As QtrFTE --Total Student FTE for the given quarter, campus, category, residency combo 
      ,Sum(st.TotalOperatingFeeAmt)         As GrossOpFeeRevenue --Gross Operating Fee for the given quarter, campus, category, residency combo
      ,Sum(st.OperatingFeeResidentPortion)  As GrossResOpFeeRevenue --Gross Resident Portion of the Operating Fee for the given given quarter, campus, category, residency combo
      ,Sum(ISNULL(wt.OpWvr,0))              As OpFeeWaivers --Total Waiver Amount that Applies to the Operating Fee for the given given quarter, campus, category, residency combo
Into #GrossOpWithWaivers 
From  ##StudentTuitionNewTC st
Left Join #QuarterlyWaiverTotal wt
  On  st.AcademicQtrKeyId = wt.AcademicQtrKeyId 
  And st.SDBSrcSystemKey = wt.SDBSrcSystemKey
Left Join #ABB_FTE fte --ABB FTE information prepared earlier.
  On  fte.AcademicQtrKeyId = st.AcademicQtrKeyId
  And fte.SDBSrcSystemKey = st.SDBSrcSystemKey
Where st.AcademicFiscalYr between @StartFY and @EndFY
Group By st.AcademicFiscalYr
        ,st.AcademicQtrKeyId
        ,st.TuitionCampus
        ,st.TuitionGroup
        ,st.TuitionGroupName
        ,Right('0'+convert(varchar(2),TuitionGroup),2)+' - '+TuitionGroupName 
        ,st.TuitionCategory
        ,st.TuitionCategoryName
        ,st.TuitionResidency
        ,st.TuitionResidencyName
        ,Case 
           When TuitionGroup=1 and TuitionResidency=1 Then '1. Undergraduate Resident' 
           When TuitionGroup=1 and TuitionResidency=2 Then '2. Undergraduate Nonresident' 
           When TuitionGroup>1 and TuitionResidency=1 Then '3. Grad/Prof Resident' 
           When TuitionGroup>1 and TuitionResidency=2 Then '4. Grad/Prof Nonresident' 
         End

/******************************************************
Net Revenue Step 5: Calculate Uncalibrated Net Revenue
*******************************************************/

--Ultimately, the revenue pools needed must be calibrated to actual collections estimated as of Spring census day of a fiscal year. Step 4 calculates calibrated net revenue.
--Uncalibrated net revenue is calculated as gross revenue less waivers less the Need/Merit pool less the Set Aside.
--     The Need/Merit pool of aid is calculated as 4% of the resident portion of the op fee charged
--     Prior to FY17, the financial aid set-aside amount is calculated as 5% of gross revenue less waivers less the need/merit pool. 
--       Starting with FY17, it is calculated at 4%, and that is the value needed for calibration. The legislature officially changed the set-aside from 5% to 4% for FY16, 
--       but it was not possible to get the change put into the system in time, so 5% is still the appropriate amount to use for FY16 calibration. 

Select AcademicFiscalYr
      ,AcademicQtrKeyId
      ,TuitionCampus
      ,TuitionGroup
      ,TuitionGroupName
      ,TGsort
      ,TuitionCategory
      ,TuitionCategoryName
      ,TuitionResidency
      ,TuitionResidencyName
      ,StdtLvl
      ,AnnualHeadcount
      ,QtrHeadcount
      ,AnnualFTE
      ,QtrFTE
      ,GrossOpFeeRevenue
      ,GrossResOpFeeRevenue
      ,OpFeeWaivers
      ,.04*GrossResOpFeeRevenue As NeedMeritPool
      ,Case
         When AcademicFiscalYr<2017  Then .05*(GrossOpFeeRevenue-OpFeeWaivers-.04*GrossResOpFeeRevenue) 
         When AcademicFiscalYr>=2017 Then .04*(GrossOpFeeRevenue-OpFeeWaivers-.04*GrossResOpFeeRevenue) 
       End As LegSetAside 
      ,Case
         When AcademicFiscalYr<2017  Then GrossOpFeeRevenue-OpFeeWaivers-.04*GrossResOpFeeRevenue-.05*(GrossOpFeeRevenue-OpFeeWaivers-.04*GrossResOpFeeRevenue) 
         When AcademicFiscalYr>=2017 Then GrossOpFeeRevenue-OpFeeWaivers-.04*GrossResOpFeeRevenue-.04*(GrossOpFeeRevenue-OpFeeWaivers-.04*GrossResOpFeeRevenue) 
       End As UncalibratedNetRevenue
Into #UncalibratedNetRevenue
From #GrossOpWithWaivers


/*****************************************************
Net Revenue Step 6: Calculate Calibrated Net Revenue
******************************************************/

--The following calculates the final calibrated net revenue calculation for prior years. Currently, we calibrate to collections by fiscal year and campus. To do so: 
--   First, we must calibrate to collections.  To do so, we calculate a calibration factor, which is applied to both gross revenue and waivers.
--   Second, we must subtract two additional forms of aid:
--      1. The UW has chosen to still set-aside 5% rather than 4% of collections for aid, but the extra aid is now called "UWSetAside". This must be subtracted.
--      2. The additional aid pools, discussed in ABB documentation, must also be subtracted. 

--6.a: Calculate and apply Calibration Factor

--6.a1: To do the calibration factor calculation, we must start with total uncalibrated revenue for each campus, which summed and put in the temp table #NetByCampus

Select AcademicFiscalYr
      ,TuitionCampus
      ,Sum(UncalibratedNetRevenue) As UNet
Into #NetByCampus
From #UncalibratedNetRevenue
Group By AcademicFiscalYr
        ,TuitionCampus

--6.a2: The calibration factor is calculated as actual collections divided by uncalibrated revenue by campus. 
----Actual operating fee collections by campus can be found in the table, OPB_ActualCollections


Select n.AcademicFiscalYr
      ,n.TuitionCampus
      ,a.ActualOperatingFeeCollectionsAmt/n.UNet  As CF
Into #CalibrationFactor
From #NetByCampus n
Inner Join AnalyticInteg.sec.OPB_ActualCollections a
  On  a.AcademicFiscalYr = n.AcademicFiscalYr
  And a.TuitionCampus = n.TuitionCampus
Where n.Unet>0 
  And a.ActualOperatingFeeCollectionsAmt>0


--6.a3: Apply Calibration Factor: GrossOp, GrossROp, and the OpWvr values are each multiplied by the calibration factor. 
----It is assumed that the same calibration factor can be applied to each quarter. While this assumption may not be quite accurate, 
----doing so enables us to provide net revenue information by academic quarter for those who need it.

Select u.AcademicFiscalYr
      ,u.AcademicQtrKeyId
      ,u.TuitionCampus
      ,u.TuitionGroup
      ,u.TuitionGroupName
      ,u.TGsort
      ,u.TuitionCategory
      ,u.TuitionCategoryName
      ,u.TuitionResidency
      ,u.TuitionResidencyName
      ,u.StdtLvl
      ,cast(u.AnnualHeadcount as decimal (6,0)) As AnnualHC
      ,cast(u.QtrHeadcount as decimal (6,0)) as QtrHC
      ,cast(u.AnnualFTE as decimal (6,0)) as AnnualFTE
      ,cast(u.QtrFTE as decimal (6,0)) as QtrFTE
      ,c.CF*u.GrossOpFeeRevenue As GrossOp
      ,c.CF*u.GrossResOpFeeRevenue As GrossResOp
      ,c.CF*u.OpFeeWaivers As OpWaivers
Into #CalibratedNetRevenueS1
From #UncalibratedNetRevenue u
Inner Join #CalibrationFactor c 
  On  c.AcademicFiscalYr = u.AcademicFiscalYr 
  And c.TuitionCampus = u.TuitionCampus


--6.b: Subtraction of UW Set-Aside and additional aid. The inclusion of 1% UW Set-Aside is explained above at the beginning of Step 6. 
----In addition, as explained in ABB documentation, there are "additional aid pools" that are subtracted from net revenue prior to distribution. Currently, there are two pools. 
----The first is a pool of aid for resident undergrads that is taken from undergraduate revenue. It was first created by legislative requirement in 2009-10, the first recent 
----year in which the UW experienced double-digit tuition increases. As tuition has increased further, the pool has increased each year. The precise portion of incremental 
----revenue that has been added was approved by the Regents each year, but the rationale behind the specific annual calculation has varied from year to year. 
----For Seattle domestic non-residents, another additional pool was created in FY14 to help attract domestic nonresidents.

----The calculations of the Need/Merit pool, Set-Aside, and net revenue are done first, as in Step 3. Then the additional aid pools are subtracted to get the FinalNetRevenue. 
----The values for the additional aid pools can be found in OPB_AdditionalAidPool. 
----The final temporary table created, which provides calibrated net revenue by year, campus, and tuition group, is ##CalibratedNetRevByTG.

--Step 6.b.1 Calculate NetOp (before additional aid)

Select
       AcademicFiscalYr
      ,AcademicQtrKeyId
      ,TuitionCampus
      ,TuitionGroup
      ,TuitionGroupName
      ,TGsort
      ,TuitionCategory
      ,TuitionCategoryName
      ,TuitionResidency
      ,TuitionResidencyName
      ,StdtLvl
      ,AnnualHC
      ,AnnualFTE
      ,GrossOp
      ,GrossResOp
      ,OpWaivers
      ,.04*GrossResOp As NMPool
      ,Case 
         When AcademicFiscalYr>=2017 Then .04*(GrossOp-OpWaivers-.04*GrossResOp) 
         When AcademicFiscalYr<2017  Then .05*(GrossOp-OpWaivers-.04*GrossResOp) 
       End As LegSetAside
-- Even though for purposes of calibration we use 4% for the set-aside beginning in FY17, it should be noted that for aid purposes, we now take out 4% for legislated set and 1% for "UWSetAside".
      ,Case when AcademicFiscalYr>=2017 then .01*(GrossOp-OpWaivers-.04*GrossResOp)  Else 0 End As UWSetAside 
      ,GrossOp - OpWaivers - .04*GrossResOp 
        -(Case 
           When AcademicFiscalYr>=2017 Then .04*(GrossOp-OpWaivers-.04*GrossResOp)
           When AcademicFiscalYr<2017  Then .05*(GrossOp-OpWaivers-.04*GrossResOp) 
          End)
        -(Case when AcademicFiscalYr>=2017 then .01*(GrossOp-OpWaivers-.04*GrossResOp) Else 0 End) As NetOpB4Addl
   
Into #CalibratedNetRevenueS2
From #CalibratedNetRevenueS1 


--Step 6.b.2 In this step, we sum over quarter to achieve the same granularity as found in the additional aid pool table.

Select
       AcademicFiscalYr
      ,TuitionCampus
      ,TuitionGroup
      ,TuitionGroupName
      ,TGsort
      ,TuitionCategory
      ,TuitionCategoryName
      ,TuitionResidency
      ,TuitionResidencyName
      ,StdtLvl
      ,SUM(AnnualHC) as HC
      ,SUM(AnnualFTE) as FTE
      ,SUM(GrossOp) as GOp
      ,SUM(GrossResOp) as GROp
      ,SUM(OpWaivers) as Waivers
      ,SUM(NMPool) as NMPool
      ,SUM(LegSetAside) as LegSetAside
      ,SUM(UWSetAside) as UWSetAside
      ,SUM(NetOpB4Addl) as NetOpB4Addl
   
Into #CalibratedNetRevenueS3
From #CalibratedNetRevenueS2 

Group by
       AcademicFiscalYr
      ,TuitionCampus
      ,TuitionGroup
      ,TuitionGroupName
      ,TGsort
      ,TuitionCategory
      ,TuitionCategoryName
      ,TuitionResidency
      ,TuitionResidencyName
      ,StdtLvl

--Step 5.b.3 - Subtract additional aid pool

Select
       n.AcademicFiscalYr
      ,n.TuitionCampus
      ,n.TuitionGroup
      ,n.TuitionGroupName
      ,n.TGsort
      ,n.TuitionCategory
      ,n.TuitionCategoryName
      ,n.TuitionResidency
      ,n.TuitionResidencyName
      ,n.StdtLvl
      ,n.HC
      ,n.FTE
      ,n.GOp
      ,n.GROp
      ,n.Waivers
      ,n.NMPool
      ,n.LegSetAside
      ,n.UWSetAside
      ,n.NetOpB4Addl
      ,ISNULL(a.AdditionalAidPoolAmt,0) as AddlAid
      ,n.NetOpB4Addl-ISNULL(a.AdditionalAidPoolAmt,0) as NetOp
Into #CalibratedNetRevenueS4
From #CalibratedNetRevenueS3 n
Left Join AnalyticInteg.sec.OPB_AdditionalAidPool a
  On  a.AcademicFiscalYr=n.AcademicFiscalYr 
  And a.TuitionCampus=n.TuitionCampus 
  And a.TuitionCategory=n.TuitionCategory
  And a.TuitionResidency=n.TuitionResidency

--Step 6.b.4 - separate out Bothell's portion of PharmD/BothellMBA revenue.
----When the PharmD/BothellMBA program was created, it was agreed that half of the revenue from these students (in their 2nd and 3rd years) 
----would be transferred to Bothell, and half would remain at Seattle and run through ABB calculations.

Select
       AcademicFiscalYr
      ,TuitionCampus
      ,TuitionCategory
      ,TuitionCategoryName
      ,TuitionGroup
      ,TuitionGroupName
      ,TuitionResidency
      ,TuitionResidencyName
      ,Case when AcademicFiscalYr>=2017 then HC/2 Else 0 End as HC
      ,Case when AcademicFiscalYr>=2017 then FTE/2 Else 0 End as FTE
      ,Case when AcademicFiscalYr>=2017 then GOp/2 Else 0 End as GOp
      ,Case when AcademicFiscalYr>=2017 then Waivers/2 Else 0 End as Waivers
      ,Case when AcademicFiscalYr>=2017 then NMPool/2 Else 0 End as NMPool
      ,Case when AcademicFiscalYr>=2017 then LegSetAside/2 Else 0 End as LegSetAside
      ,Case when AcademicFiscalYr>=2017 then UWSetAside/2 Else 0 End as UWSetAside
      ,Case when AcademicFiscalYr>=2017 then NetOpB4Addl/2 Else 0 End as NetOpB4Addl
      ,Case when AcademicFiscalYr>=2017 then AddlAid/2 Else 0 End as AddlAid
      ,Case when AcademicFiscalYr>=2017 then NetOp/2 Else 0 End as NetOp
Into #PharmDBothellMBA
From #CalibratedNetRevenueS4
Where TuitionCampus=0 and TuitionCategory=87

--Step 6.b.5 - Here we subtract off Bothell's portion of PharmD/BothellMBA tuition and aggregate revenue to tuition group

Select 
     r.AcademicFiscalYr
    ,r.TuitionCampus
    ,r.TuitionGroup
    ,r.TuitionGroupName
    ,r.TGsort
    ,SUM(r.HC-ISNULL(p.HC,0)) as HC
    ,SUM(r.FTE-ISNULL(p.FTE,0)) as FTE
    ,SUM(r.GOp-ISNULL(p.GOp,0)) as GOp
    ,SUM(r.Waivers-ISNULL(p.Waivers,0)) As Waivers
    ,SUM(r.NMPool-ISNULL(p.NMPool,0)) as NMPool
    ,SUM(r.LegSetAside-ISNULL(p.LegSetAside,0)) As LegSetAside
    ,SUM(r.UWSetAside-ISNULL(p.UWSetAside,0)) as UWSetAside
    ,SUM(r.NetOpB4Addl-ISNULL(p.NetOpB4Addl,0)) as NetOpB4Addl
    ,SUM(r.AddlAid-ISNULL(p.AddlAid,0)) as AddlAid
    ,SUM(r.NetOp-ISNULL(p.NetOp,0)) As NetOp
Into ##CalibratedNetRevenueByTG
From #CalibratedNetRevenueS4 r
Left Join #PharmDBothellMBA p
  On r.AcademicFiscalYr=p.AcademicFiscalYr and
     r.TuitionCampus=p.TuitionCampus and
     r.TuitionCategory=p.TuitionCategory and
     r.TuitionResidency=p.TuitionResidency
Group by
     r.AcademicFiscalYr
    ,r.TuitionCampus
    ,r.TuitionGroup
    ,r.TuitionGroupName
    ,r.TGsort

  
/***********************************************
Distribution Step 1: Calculating SCH Percentage
************************************************/

--1.a The SCHbyTGbyCollege CTE determines the number of ABB SCH from each tuition group generated by each school/college for each academic fiscal year (FWS). Note that, for ABB calculation purposes, students paying tuition to another campus are excluded, as are SCH taken at another campus. The one exception to this is for students in the PharmD/Bothell MBA program. The tuition revenue from that group is split between Seattle and Bothell. However, all Seattle SCH taken by these students are included - the assumption is that the SCH taken at Bothell correspond to the tuition revenue that is transferred to Bothell, so all Seattle SCH should be included in the ABB calculations.

;With SCHbyTGbyCollege As
(
Select s.AcademicFiscalYr
      ,s.TuitionGroup
      ,s.TuitionGroupName
      ,Left(cfo.FinCollegeNbr,3) As Coll
      ,cfo.FinCollegeReportingName As CollName
      ,cast(SUM(ABBSCHQty) as decimal (20,10)) As SCH
From  ##StudentTuitionNewTC s
Left Join  AnalyticInteg.sec.ABB_CourseSectionRegistrations r
   On  s.AcademicQtrKeyId = r.AcademicQtrKeyId 
   And s.SDBSrcSystemKey = r.SDBSrcSystemKey 
Left Join AnalyticInteg.sec.ABB_CurriculumFinancialOrganizations cfo
   On  r.AcademicFiscalYr=cfo.AcademicFiscalYr
   And r.ResponsibleCurriculumCode=cfo.CurriculumCode
Where cfo.CurriculumCampus=0                    --This excludes SCH taken at Bothell or Tacoma
  And s.TuitionCampus=0                         --This excludes SCH associated with students paying either Bothell or Tacoma tuition
  And s.AcademicFiscalYr between @StartFY and @EndFY
  And r.NonSummerInd='Y'                        --This eliminates Summer quarter SCH.
Group By s.AcademicFiscalYr
        ,s.TuitionGroup
        ,s.TuitionGroupName
        ,Left(cfo.FinCollegeNbr,3)
        ,cfo.FinCollegeReportingName
)

--1.b To provide the denominator for the percentage calculations, the TotSCHbyTG CTE sums SCH by year by tuition group across colleges.

,TotSCHbyTG As
(
 Select AcademicFiscalYr
       ,TuitionGroup
       ,TuitionGroupName
       ,cast(SUM(SCH) as decimal (20,10)) As TotSCH
 From SCHbyTGbyCollege
 Group By AcademicFiscalYr
         ,TuitionGroup
         ,TuitionGroupName
)

--1.c The numerator calculated in SCHbyTGbyCollege and the denominator calculated in TotSCHbyTG are combined to calculate the percentage of SCH from each tuition group generated by each college. The values are stored in the temporary table, ##PcntSCHbyTGbyCollege.  

Select sg.AcademicFiscalYr
      ,sg.TuitionGroup
      ,sgc.Coll
      ,sgc.CollName
      ,Case When sg.TotSCH>0 Then sgc.SCH/sg.TotSCH Else 0 End as PercentSCH
Into #PercentageSCHbyTuitionGroupByCollege
From TotSCHbyTG sg
Left Join SCHbyTGbyCollege sgc
  On  sg.AcademicFiscalYr=sgc.AcademicFiscalYr 
  And sg.TuitionGroup=sgc.TuitionGroup

/*********************************************************
Distribution Step 2: Calculating Percentage Degree Majors
**********************************************************/

--2.a The DegreeMajorsByCollege CTE determines the number of Seattle undergraduate bachelor's degree majors in a given academic fiscal year awarded by each school/college. This will provide the numerator for the % degree major calculation by which undergraduate tuition will be distributed under ABB. Note that we are creating a new field, "ABBYr". This is the year to which the %Degs should be applied for calculation purposes. Degrees are lagged by one year for the purpose of ABB tuition revenue distributions.

; With DegreeMajorsByCollege As
(
Select c.AcademicFiscalYr               --This is the academic year in which the degree was awarded.
      ,c.AcademicFiscalYr+1 As ABBYr    --Given when degree data are complete, we have to use degree data from one year ago to distribute revenue for the current year. ABBYr is the revenue year to which the percentage degree majors should be applied.
      ,0 as Campus
      ,Left(dfo.FinCollegeNbr,3) As Coll
      ,dfo.FinCollegeReportingName as CollName
      ,1 As TuitionGroup
      ,Convert(decimal(20,10), Count(c.SDBSrcSystemKey)) As NumDegMjrs
From AnalyticInteg.sec.ABB_UndergraduateDegreeMajorCompletions c
Left Join AnalyticInteg.sec.ABB_DegreeFinancialOrganizations dfo
  On  c.AcademicFiscalYr=dfo.AcademicFiscalYr 
  And c.DegreeCode=dfo.DegreeCode
Where FinCampusNbr='SEA'                --Only degree majors from Seattle should be included.
Group By c.AcademicFiscalYr
        ,c.AcademicFiscalYr+1
        ,Left(dfo.FinCollegeNbr,3) 
        ,dfo.FinCollegeReportingName)   


--2.b The TotDegByYr CTE calculates the total number of degree majors per year from the temp table, ##BachDegreesByCollege. Only bachelor degree majors from Seattle are included.

,TotDegByYr As
(
Select 
         bdc.ABBYr
        ,bdc.TuitionGroup
        ,cast(SUM(NumDegMjrs) as decimal (20,10)) As TotDegs
From DegreeMajorsByCollege bdc
Group By 
         bdc.ABBYr
        ,bdc.TuitionGroup
)
--2.c The temp table ##BachDegreesByCollege is combined with the TotDegByYr CTE to calculate the percentage degrees by college per year.
Select bdc.ABBYr
      ,bdc.TuitionGroup
      ,bdc.Coll
      ,bdc.CollName
      ,Case When td.TotDegs>0 Then bdc.NumDegMjrs/td.TotDegs else 0 End As PcntDegs 
Into #PercentageDegreeMajorsByCollege
From DegreeMajorsByCollege bdc
Inner Join TotDegByYr td
  On td.ABBYr=bdc.ABBYr


/**************************************************************
Distribution Step 3: Calculating Percentage Major Enrollments
***************************************************************/

--3.a The MajorEnrollByTGbyColl CTE provides the count of major enrollments for grad/professional students by tuition group and college for the academic year (FWS). 
      --Only students with a Seattle tuition category and Seattle majors are included.

;With MajorEnrollByTGbyColl As
(
Select s.AcademicFiscalYr
      ,s.TuitionGroup
      ,s.TuitionGroupName
      ,Left(mfo.FinCollegeNbr,3) As Coll
      ,mfo.FinCollegeReportingName as CollName
      ,Convert(decimal(20,10), count(m.SDBSrcSystemKey)) As Majors
From ##StudentTuitionNewTC s
Left Join AnalyticInteg.sec.ABB_GraduateMajorProgramEnrollments m
  On  s.AcademicQtrKeyId=m.AcademicQtrKeyId 
  And s.SDBSrcSystemKey=m.SDBSrcSystemKey 
Left Join AnalyticInteg.sec.ABB_MajorFinancialOrganizations mfo
   On  m.AcademicFiscalYr=mfo.AcademicFiscalYr 
   And m.MajorCode=mfo.MajorCode
Where mfo.MajorCampus=0
  And s.TuitionCampus=0 
  And s.AcademicFiscalYr between @StartFY and @EndFY
  And s.TuitionGroup >1 
  And m.NonSummerInd='Y'
Group By s.AcademicFiscalYr
        ,s.TuitionGroup
        ,s.TuitionGroupName
        ,Left(mfo.FinCollegeNbr,3) 
        ,mfo.FinCollegeReportingName)

--3.b To provide the denominator for the percentage calculations, the TotMjrsbyTG CTE sums Majors by year by tuition group across colleges.
,TotMjrsbyTG As
(
Select AcademicFiscalYr
      ,TuitionGroup
      ,TuitionGroupName
      ,cast(SUM(Majors) as decimal (20,10)) As TotMjrs
From MajorEnrollByTGbyColl
Group By AcademicFiscalYr
        ,TuitionGroup
        ,TuitionGroupName
)
--3.c The numerator calculated in TotMjrsbyTGbyCollege and the denominator calculated in TotMjrsbyTG are combined to calculate the percentage of Majors from each tuition group generated by each college. The values are stored in the temporary table, #PercentMajorEnrollmentsByTGbyCollege.  
Select mg.AcademicFiscalYr
      ,mg.TuitionGroup
      ,mgc.Coll
      ,mgc.CollName
      ,Case When mg.TotMjrs>0 Then mgc.Majors/mg.TotMjrs Else 0 End As PcntMjrs
Into #PercentageMajorEnrollmentsByTGbyCollege
From TotMjrsbyTG mg
Left Join MajorEnrollByTGbyColl mgc
  On  mg.AcademicFiscalYr=mgc.AcademicFiscalYr 
  And mg.TuitionGroup=mgc.TuitionGroup
/**************************************************************************
Distribution Step 4: Calculating Amount Distributed to Schools and Colleges
***************************************************************************/
--4.a.0 Create list of all years
;With Years As
(Select Distinct AcademicFiscalYr
   From AnalyticInteg.Sec.dimDate
   Where AcademicFiscalYr between @StartFY and @EndFY
)
--4.a.1 Create a Master List of all Tuition Groups
,TuitionGroups As
(Select Distinct 
        AcademicFiscalYr
       ,TuitionGroup    
       ,TuitionGroupName
       ,TGsort
   From ##CalibratedNetRevenueByTG
   Where TuitionCampus=0
)
--4.a.2 Create a Master List of all Colleges
,Colleges As
(
 Select Distinct s.Coll ,s.CollName From #PercentageSCHbyTuitionGroupByCollege s
 Union
 Select Distinct m.Coll ,m.CollName From #PercentageMajorEnrollmentsByTGbyCollege m
 Union 
 Select Distinct d.Coll ,d.CollName From #PercentageDegreeMajorsByCollege d
)
--4.a.3 Create list including all included year, tuition groups, and schools/colleges
Select y.AcademicFiscalYr
      ,t.TuitionGroup
      ,t.TuitionGroupName
      ,t.TGsort
      ,c.Coll
      ,c.CollName
  Into #TGbyCollegeByFY
  From Years y
  Left Join TuitionGroups t
    On y.AcademicFiscalYr=t.AcademicFiscalYr
  Cross Join Colleges c
  
--4.b Gather all of the percentages together into one record per Fiscal Year per School/Colleg per Tuition Group. 
--Uses the results from the following temp tables:
      --#PercentSCHbyTuitionGroupByCollege
      --#PercentDegreeMajorsByCollege  
      --#PercentMajorEnrollmentsByTGbyCollege
Select
  t.AcademicFiscalYr
 ,t.TuitionGroup
 ,t.TuitionGroupName
 ,t.TGsort
 ,t.Coll
 ,t.CollName
 ,ISNULL(s.PercentSCH,0) As PercentSCH
 ,ISNULL(m.PcntMjrs,0) As PcntMjrs
 ,ISNULL(d.PcntDegs,0) As PcntDegs

Into #Pcnts
From #TGbyCollegeByFY t
Left Join #PercentageSCHbyTuitionGroupByCollege s
  On  s.AcademicFiscalYr=t.AcademicFiscalYr 
  And t.Coll=s.Coll
  And t.TuitionGroup=s.TuitionGroup
Left Join #PercentageMajorEnrollmentsByTGbyCollege m
  On  t.AcademicFiscalYr=m.AcademicFiscalYr 
  And t.Coll=m.coll
  And t.TuitionGroup=m.TuitionGroup
Left Join #PercentageDegreeMajorsByCollege d
  On  t.AcademicFiscalYr=d.ABBYr 
  And t.TuitionGroup=d.TuitionGroup 
  And t.Coll=d.coll


--4.c Calculate Net Revenue to be distributed to the given School/College for the given Tuition Group starting with FY18 (and we need to calculate it for FY17 final to calculate incremental revenue.
--This is done by applying the percentages calculated in previous steps to the Net Revenue calculated in ##CalibratedNetRevenueByTG, with the addition of the tax rate and distribution parameters
----1. Applying the 70% adjustment to net revenue to get the amount that is to be distributed after the 30% tax is applied
----2. Applying the ABB Distribution Rules in effect as of FY18:
-------- 2a. For Undergraduate Revenue (Tuition Group 1):
------------ 80% is based on Student Credit Hours produced by the School/College
------------ 20% is based on Bachelors Degrees Awarded by the School/College (in the previous Fiscal Year compared to SCH)
-------- 2b. For Graduate and Professional Revenue (Tuition Groups >1):
------------ 80% is based on Student Credit Hours produced by the School/College
------------ 20% is based on Grad/Professional Major/Program Enrollments for the School/College 



Select p.AcademicFiscalYr
      ,p.TuitionGroup
      ,p.TuitionGroupName
      ,p.TGsort
      ,p.Coll
      ,p.CollName
      ,p.Coll+' - '+p.CollName As College
      ,(Case When p.TuitionGroup In(4,8) Then 0.7*0.2*PercentSCH Else 0.7*0.8*PercentSCH End)*ISNULL(NetOp,0)  As RevFromSCH
      ,(Case When p.TuitionGroup=1 Then 0.7*.2*PcntDegs When p.TuitionGroup in (4,8) Then 0.7*0.8*PcntMjrs Else 0.7*0.2*PcntMjrs End)*ISNULL(NetOp,0)  As RevFromDegsMjrs
      ,(Case When p.TuitionGroup=1 Then 0.7*.2*PcntDegs When p.TuitionGroup in (4,8) Then 0.7*0.8*PcntMjrs Else 0.7*0.2*PcntMjrs End)*ISNULL(NetOp,0)
           +(Case When p.TuitionGroup In(4,8) Then 0.7*0.2*PercentSCH Else 0.7*0.8*PercentSCH End)*ISNULL(NetOp,0) As TotRev
Into #RevByTGbyColl
From #Pcnts p
Left Join ##CalibratedNetRevenueByTG r --The Calibrated Net Revenue By Tuition Group 
  On  r.AcademicFiscalYr = p.AcademicFiscalYr 
  And r.TuitionGroup = p.TuitionGroup 
Where r.AcademicFiscalYr<=2017 and r.TuitionCampus=0
Order By p.AcademicFiscalYr
        ,p.TuitionGroup
        ,p.TuitionGroupName
        ,p.TGsort
        ,p.Coll
        ,p.CollName

Select
       AcademicFiscalYr
      ,Coll
      ,CollName
      ,College
      ,SUM(TotRev) as TotRev

From #RevByTGbyColl
Group by
       AcademicFiscalYr
      ,Coll
      ,CollName
      ,College




