
--This file produces the output that can be used to support projections. It breaks out students into all the new tuition categories and uses the new distribution rules. The major difference between this file and NetRevenueToUnitsNewParameters is that projections require a different level of granularity, which this file supports.


SET NOCOUNT ON

Declare @BaseFY as int=2017

--The following drop table commands are included for any temporary tables created below.
If Object_ID('tempdb..#ABB_FTE') Is not null drop table #ABB_FTE
If Object_ID('tempdb..#QuarterlyWaiverTotal') Is not null drop table #QuarterlyWaiverTotal
If Object_ID('tempdb..#GrossOpWithWaivers') Is not null drop table #GrossOpWithWaivers
If Object_ID('tempdb..#GradSchoolStdts') Is not null drop table #GradSchoolStdts
If Object_ID('tempdb..#Law3') Is not null drop table #Law3
If Object_ID('tempdb..#TacomaSW') Is not null drop table #TacomaSW
If Object_ID('tempdb..#StudentTuitionNewTC') Is not null drop table #StudentTuitionNewTC
If Object_ID('tempdb..#UncalibratedNetRevenue') Is not null drop table #UncalibratedNetRevenue
If Object_ID('tempdb..#NetByCampus') Is not null drop table #NetByCampus
If Object_ID('tempdb..#AddlAid') Is not null drop table #AddlAid
If Object_ID('tempdb..#CalibrationFactor') Is not null drop table #CalibrationFactor
If Object_ID('tempdb..#CalibratedNetRevenueS1') Is not null drop table #CalibratedNetRevenueS1
If Object_ID('tempdb..#CalibratedNetRevenueS2') Is not null drop table #CalibratedNetRevenueS2
If Object_ID('tempdb..#CalibratedNetRevenueS3') Is not null drop table #CalibratedNetRevenueS3
If Object_ID('tempdb..#CalibratedNetRevenueS4') Is not null drop table #CalibratedNetRevenueS4
If Object_ID('tempdb..#PharmDBothellMBA') Is not null drop table #PharmDBothellMBA
If Object_ID('tempdb..##CalibratedNetRevenue') Is not null drop table ##CalibratedNetRevenue
If Object_ID('tempdb..##CalibratedNetRevenueByTG') Is not null drop table ##CalibratedNetRevenueByTG
If Object_ID('tempdb..#RevByColl') Is not null drop table #RevByColl
If Object_ID('tempdb..#Pcnts') Is not null drop table #Pcnts
If Object_ID('tempdb..#TGbyCollege') Is not null drop table #TGbyCollege
If Object_ID('tempdb..#TGbyCollegeByFY') Is not null drop table #TGbyCollegeByFY
If Object_ID('tempdb..#PercentageSCHbyTuitionGroupByCollege') Is not null drop table #PercentageSCHbyTuitionGroupByCollege
If Object_ID('tempdb..#PercentageDegreeMajorsByCollege') Is not null drop table #PercentageDegreeMajorsByCollege
If Object_ID('tempdb..#PercentageMajorEnrollmentsByTGbyCollege') Is not null drop table #PercentageMajorEnrollmentsByTGbyCollege
If Object_ID('tempdb..##RevToCollOldParameters') Is not null drop table ##RevToCollOldParameters
If Object_ID('tempdb..##RevToCollNewParameters') Is not null drop table ##RevToCollNewParameters


/******************************************
Net Revenue Step 1: Calculate ABB FTE
*******************************************/

--The ABB_CourseSectionRegistrationsTable has the ABB FTE associated with each course registration calculated. 
--To calculate the quarterly FTE associated for each student, the ABB_FTE associated with all course registrations for a student are summed.

Select AcademicFiscalYr
      ,AcademicQtrKeyId
      ,SDBSrcSystemKey
      ,NonSummerInd
      ,SUM(ABBFTEQty) As ABB_FTE
Into #ABB_FTE
From AnalyticInteg.sec.ABB_CourseSectionRegistrations
Where ABBFTEQty>0 and AcademicFiscalYr=@BaseFY
Group by
       AcademicFiscalYr
      ,AcademicQtrKeyId
      ,NonSummerInd
      ,SDBSrcSystemKey
 
/******************************************************
Net Revenue Step 2: Sum waivers over waiver categories
*******************************************************/

-- The ABB_StudentWaivers table has a record for every student receiving a waiver in a quarter for every waiver category in which they receive a waiver. 
----Since there can be multiple records per student, the #QuarterlyWaiverTotal temp table, which removes the waiver category distinction and provides one record 
----(including the total waiver amount for each student receiving one or more waivers), is created (to simplify the process of joining tuition information with waiver information).

Select AcademicFiscalYr
      ,AcademicQtrKeyId
      ,SDBSrcSystemKey
      ,SUM(TotalOperatingFeeWaiverAmt) As OpWvr
      ,SUM(OperatingFeeAnyResidencyWaiverAmt) As AnyWvr
      ,SUM(OperatingFeeResidentPortionWaiverAmt) as ResWvr
      ,SUM(OperatingFeeNonResidentDifferentialWaiverAmt) as NRDWvr

Into #QuarterlyWaiverTotal
From AnalyticInteg.sec.ABB_StudentWaivers 
Where AcademicFiscalYr=@BaseFY
Group By AcademicFiscalYr
        ,AcademicQtrKeyId
        ,SDBSrcSystemKey

/******************************************************************
Net Revenue Step 3A: Reassign students to New Tuition Categories
*******************************************************************/

--Identify students enrolled in programs run by the Grad School who are currently paying Tier I or TierIII tuition.

SELECT t.AcademicFiscalYr
      ,t.AcademicQtrKeyId
      ,t.SDBSrcSystemKey
      ,t.TuitionCampus
      ,t.TuitionResidency
      ,t.TuitionResidencyName
      ,case 
            when t.TuitionCampus=0 and t.TuitionCategory=5 and m.MajorCode 
                    in ('0_MCB_00','0_NEUBEH_00','0_N&MES_00','0_UD&PL_00','0_BMSD_00','0_IPHD_00','0_MCB_10','0_BPSD_00','0_NEURO_00') 
                    then 6 
            when t.TuitionCampus=0 and t.TuitionCategory=9 and m.MajorCode like '0_MOLE%' then 10 End As TCNew1
      ,case 
            when t.TuitionCampus=0 and t.TuitionCategory=5 and m.MajorCode 
                    in ('0_MCB_00','0_NEUBEH_00','0_N&MES_00','0_UD&PL_00','0_BMSD_00','0_IPHD_00','0_MCB_10','0_BPSD_00','0_NEURO_00')
                    then 'Grad School Tier I' 
            when t.TuitionCampus=0 and t.TuitionCategory=9 and m.MajorCode like '0_MOLE%' then 'Grad School Tier III' End As TCNameNew1
      ,case 
            when t.TuitionCampus=0 and t.TuitionGroup=3 and m.MajorCode 
                    in ('0_MCB_00','0_NEUBEH_00','0_N&MES_00','0_UD&PL_00','0_BMSD_00','0_IPHD_00','0_MCB_10','0_BPSD_00','0_NEURO_00') then 4 
            when t.TuitionCampus=0 and t.TuitionGroup=7 and m.MajorCode like'0_MOLE%' then 8 End As TGNew1
      ,case 
            when t.TuitionCampus=0 and t.TuitionGroup=3 and m.MajorCode 
                    in ('0_MCB_00','0_NEUBEH_00','0_N&MES_00','0_UD&PL_00','0_BMSD_00','0_IPHD_00','0_MCB_10','0_BPSD_00','0_NEURO_00') then 'Grad School Tier I' 
            when t.TuitionCampus=0 and t.TuitionGroup=7 and m.MajorCode like'0_MOLE%' then 'Grad School Tier III' End  As TGNameNew1
  Into #GradSchoolStdts      
  FROM [AnalyticInteg].[sec].[ABB_StudentTuition] t
  Left join AnalyticInteg.sec.ABB_GraduateMajorProgramEnrollments m
    On t.AcademicQtrKeyId=m.AcademicQtrKeyId
       And t.SDBSrcSystemKey=m.SDBSrcSystemKey
          Where t.AcademicFiscalYr=2017 and 
                t.NonSummerInd='Y' and 
                    (t.TuitionCampus=0 and ((t.TuitionCategory=5 and m.MajorCode in    
                         ('0_MCB_00','0_NEUBEH_00','0_N&MES_00','0_UD&PL_00','0_BMSD_00','0_IPHD_00','0_MCB_10','0_BPSD_00','0_NEURO_00')) or 
                    (t.TuitionCampus=0 and t.TuitionCategory=9 and m.MajorCode like '0_MOLE%'))) 

--Change Tacoma Social Work students from Grad Tier I to Grad Tier II.

SELECT t.AcademicFiscalYr
      ,t.AcademicQtrKeyId
      ,t.SDBSrcSystemKey
      ,t.TuitionCampus
      ,t.TuitionResidency
      ,t.TuitionResidencyName
      ,case 
            when t.TuitionCampus=2 and t.TuitionCategory=5 and m.MajorCode like '2_T SOCW%' then 7 End as TCNew2
      ,case 
            when t.TuitionCampus=2 and t.TuitionCategory=5 and m.MajorCode like '2_T SOCW%' then 'Graduate Tier II' End as TCNameNew2
      ,case 
            when t.TuitionCampus=2 and t.TuitionGroup=3 and m.MajorCode like '2_T SOCW%' then 5 End as TGNew2
      ,case
            when t.TuitionCampus=2 and t.TuitionGroup=3 and m.MajorCode like '2_T SOCW%' then 'Graduate Tier II' End As TGNameNew2
  Into #TacomaSW      
  FROM [AnalyticInteg].[sec].[ABB_StudentTuition] t
  Left join AnalyticInteg.sec.ABB_GraduateMajorProgramEnrollments m
    On t.AcademicQtrKeyId=m.AcademicQtrKeyId
       And t.SDBSrcSystemKey=m.SDBSrcSystemKey
          Where t.AcademicFiscalYr=2017 and 
                t.NonSummerInd='Y' and 
                t.tuitionCampus=2 and t.TuitionCategory=5 and t.TuitionCampus=2 and m.MajorCode like '2_T SOCW%'

--Make new StudentTuitionTable w new categories

SELECT t.AcademicFiscalYr
      ,t.AcademicQtrKeyId
      ,t.SDBSrcSystemKey
      ,t.TuitionCampus
      ,t.TuitionResidency
      ,t.TuitionResidencyName
      ,case 
            when t.TuitionCampus=0 and t.TuitionCategory=59 and f.StudentClassCode=13 then 61 End as TCNew3
      ,case 
            when t.TuitionCampus=0 and t.TuitionCategory=59 and f.StudentClassCode=13 then 'Law (JD) 3L' End as TCNameNew3
      ,case 
            when t.TuitionCampus=0 and t.TuitionCategory=59 and f.StudentClassCode=13 then TuitionGroup End as TGNew3
      ,case
            when t.TuitionCampus=0 and t.TuitionCategory=59 and f.StudentClassCode=13 then TuitionGroupName End as TGNameNew3
  Into #Law3    
  FROM [AnalyticInteg].[sec].[ABB_StudentTuition] t
  Left join AnalyticInteg.sec.IV_StudentFactSheetBase f
    On t.AcademicQtrKeyId=f.AcademicQtrKeyId and
       t.SDBSrcSystemKey=f.SDBSrcSystemKey
  Left join AnalyticInteg.sec.ABB_GraduateMajorProgramEnrollments m
    On t.AcademicQtrKeyId=m.AcademicQtrKeyId
       And t.SDBSrcSystemKey=m.SDBSrcSystemKey
    Where t.AcademicFiscalYr=2017 and t.NonSummerInd='Y' and t.tuitionCampus=0 and t.TuitionCategory=59 and f.StudentClassCode=13

Select t.AcademicFiscalYr
      ,t.AcademicQtrKeyId 
      ,t.TuitionCampus
      ,t.SDBSrcSystemKey
      ,case when g.SDBSrcSystemKey>0 then g.TCNew1 when s.SDBSrcSystemKey>0 then s.TCNew2 when l.SDBSrcSystemKey>0 then l.TCNew3 else t.TuitionCategory End as TuitionCategory
      ,case when g.SDBSrcSystemKey>0 then g.TCNameNew1 when s.SDBSrcSystemKey>0 then s.TCNameNew2 when l.SDBSrcSystemKey>0 then l.TCNameNew3 else t.TuitionCategoryName End as TuitionCategoryName
      ,case when g.SDBSrcSystemKey>0 then g.TGNew1 when s.SDBSrcSystemKey>0 then TGNew2 when l.SDBSrcSystemKey>0 then l.TGNew3 else t.TuitionGroup End as TuitionGroup
      ,case when g.SDBSrcSystemKey>0 then g.TGNameNew1 when s.SDBSrcSystemKey>0 then TGNameNew2 when l.SDBSrcSystemKey>0 then l.TGNameNew3 else t.TuitionGroupName End as TuitionGroupName
      ,t.TuitionResidency
      ,t.TuitionResidencyName
      ,t.TotalOperatingFeeAmt
      ,t.OperatingFeeResidentPortion
Into #StudentTuitionNewTC
From  AnalyticInteg.sec.ABB_StudentTuition t
Left Join #GradSchoolStdts g
  On  t.AcademicQtrKeyId = g.AcademicQtrKeyId 
  And t.SDBSrcSystemKey = g.SDBSrcSystemKey
Left Join #TacomaSW s
  On t.AcademicQtrKeyId=s.AcademicQtrKeyId and
     t.SDBSrcSystemKey=s.SDBSrcSystemKey
Left Join #Law3 l
  On t.AcademicQtrKeyId=l.AcademicQtrKeyId and
     t.SDBSrcSystemKey=l.SDBSrcSystemKey
Where t.AcademicFiscalYr=@BaseFY and t.NonSummerInd='Y' 

/*************************************************************
Net Revenue Step 3B: Combine gross op fee revenue with waivers
**************************************************************/

--A left join is made from ABB_StudentTuition, which has each student's tuition category information as well as the operating fee charged, to the temp table, #QuarterlyWaiverTotal. 
--A left join is required because not every student receives a waiver.

Select st.AcademicFiscalYr
      ,st.AcademicQtrKeyId
      ,st.TuitionCampus
      ,st.TuitionGroup
      ,st.TuitionGroupName
      ,st.TuitionCategory
      ,st.TuitionCategoryName
      ,st.TuitionResidency
      ,st.TuitionResidencyName
      ,Count(st.SDBSrcSystemKey)/3          As AnnualHeadcount --Total Student Head Count (Annualized) for the given Academic Fiscal Year, campus, category, residency combo
      ,Count(st.SDBSrcSystemKey)            As QtrHeadcount --Total Student Head Count for the given quarter, campus, category, residency combo 
      ,Sum(fte.ABB_FTE)/3                   As AnnualFTE --Total (Annualized) Student FTE for the given Academic Fiscal Year, campus, category, residency combo
      ,Sum(fte.ABB_FTE)                     As QtrFTE --Total Student FTE for the given quarter, campus, category, residency combo 
      ,Sum(st.TotalOperatingFeeAmt)         As GrossOpFeeRevenue --Gross Operating Fee for the given quarter, campus, category, residency combo
      ,Sum(st.OperatingFeeResidentPortion)  As GrossResOpFeeRevenue --Gross Resident Portion of the Operating Fee for the given given quarter, campus, category, residency combo
      ,Sum(ISNULL(wt.OpWvr,0))              As OpWvr --Total Waiver Amount that Applies to the Operating Fee for the given given quarter, campus, category, residency combo
      ,Sum(ISNULL(wt.AnyWvr,0))             As AnyWvr --Waiver Amount that Applies to the Operating Fee for the given given quarter, campus, category, residency combo,regardless of residency
      ,Sum(ISNULL(wt.ResWvr,0))             As ResWvr --Waiver Amount that Applies to the resident portion of the operating Fee for the given given quarter, campus, category, residency combo
      ,Sum(ISNULL(wt.NRDWvr,0))             As NRDWvr --Waiver Amount that Applies to the Nonresident differential of the operating Fee for the given given quarter, campus, category, residency combo
Into #GrossOpWithWaivers 
From  #StudentTuitionNewTC st
Left Join #QuarterlyWaiverTotal wt
  On  st.AcademicQtrKeyId = wt.AcademicQtrKeyId 
  And st.SDBSrcSystemKey = wt.SDBSrcSystemKey
Left Join #ABB_FTE fte --ABB FTE information prepared earlier.
  On  fte.AcademicQtrKeyId = st.AcademicQtrKeyId
  And fte.SDBSrcSystemKey = st.SDBSrcSystemKey
Left Join AnalyticInteg.sec.IV_StudentFactSheetBase f --FactSheet is used to obtain StudentClass for professional students 
  On st.AcademicQtrKeyId=f.AcademicQtrKeyId
     And st.SDBSrcSystemKey=f.SDBSrcSystemKey
Where st.AcademicFiscalYr=@BaseFY --we only want Autumn, Winter and Spring Quarters for ABB. 
Group By st.AcademicFiscalYr
        ,st.AcademicQtrKeyId
        ,st.TuitionCampus
        ,st.TuitionGroup
        ,st.TuitionGroupName
        ,st.TuitionCategory
        ,st.TuitionCategoryName
        ,st.TuitionResidency
        ,st.TuitionResidencyName


/******************************************************
Net Revenue Step 4: Calculate Uncalibrated Net Revenue
*******************************************************/

--Ultimately, the revenue pools needed must be calibrated to actual collections estimated as of Spring census day of a fiscal year. Step 4 calculates calibrated net revenue.
--Uncalibrated net revenue is calculated as gross revenue less waivers less the Need/Merit pool less the Set Aside.
--     The Need/Merit pool of aid is calculated as 4% of the resident portion of the op fee charged
--     Prior to FY17, the financial aid set-aside amount is calculated as 5% of gross revenue less waivers less the need/merit pool. 
--       Starting with FY17, it is calculated at 4%, and that is the value needed for calibration. The legislature officially changed the set-aside from 5% to 4% for FY16, 
--       but it was not possible to get the change put into the system in time, so 5% is still the appropriate amount to use for FY16 calibration. 

Select AcademicFiscalYr
      ,AcademicQtrKeyId
      ,TuitionCampus
      ,TuitionGroup
      ,TuitionGroupName
      ,Right('0'+convert(varchar(2),TuitionGroup),2)+' - '+TuitionGroupName As TGsort 
      ,TuitionCategory
      ,TuitionCategoryName
      ,TuitionResidency
      ,TuitionResidencyName
      ,Case 
         when TuitionGroup=1 and TuitionResidency=1 then '1. Undergraduate Resident' 
         when TuitionGroup=1 and TuitionResidency=2 then '2. Undergraduate Nonresident' 
         when TuitionGroup>1 and TuitionResidency=1 then '3. Grad/Prof Resident' 
         when TuitionGroup>1 and TuitionResidency=2 then '4. Grad/Prof Nonresident' 
       End As StdtLvl -- In a number of instances, we need to break out revenue into these four groups
      ,AnnualHeadcount
      ,QtrHeadcount
      ,AnnualFTE
      ,QtrFTE
      ,GrossOpFeeRevenue
      ,GrossResOpFeeRevenue
      ,OpWvr
      ,AnyWvr
      ,ResWvr
      ,NRDWvr
      ,.04*GrossResOpFeeRevenue As NeedMeritPool
      ,Case
         when AcademicFiscalYr<2017  then .05*(GrossOpFeeRevenue-OpWvr-.04*GrossResOpFeeRevenue) 
         when AcademicFiscalYr>=2017 then .04*(GrossOpFeeRevenue-OpWvr-.04*GrossResOpFeeRevenue) 
       End As LegSetAside 
      ,Case
         when AcademicFiscalYr<2017 then GrossOpFeeRevenue-OpWvr-.04*GrossResOpFeeRevenue-.05*(GrossOpFeeRevenue-OpWvr-.04*GrossResOpFeeRevenue) 
         when AcademicFiscalYr>=2017 then GrossOpFeeRevenue-OpWvr-.04*GrossResOpFeeRevenue-.04*(GrossOpFeeRevenue-OpWvr-.04*GrossResOpFeeRevenue) 
       End As UncalibratedNetRevenue
Into #UncalibratedNetRevenue
From #GrossOpWithWaivers


/*****************************************************
Net Revenue Step 5: Calculate Calibrated Net Revenue
******************************************************/

--The following calculates the final calibrated net revenue calculation for prior years. Currently, we calibrate to collections by fiscal year and campus. To do so: 
--   First, we must calibrate to collections.  To do so, we calculate a calibration factor, which is applied to both gross revenue and waivers.
--   Second, we must subtract two additional forms of aid:
--      1. The UW has chosen to still set-aside 5% rather than 4% of collections for aid, but the extra aid is not called "UWSetAside". This must be subtracted.
--      2. The additional aid pools, discussed in ABB documentation, must also be subtracted. 

--5.a: Calculate and apply Calibration Factor

--5.a1: To do the calibration factor calculation, we must start with total uncalibrated revenue for each campus, which summed and put in the temp table #NetByCampus

Select AcademicFiscalYr
      ,TuitionCampus
      ,Sum(UncalibratedNetRevenue) As UNet
Into #NetByCampus
From #UncalibratedNetRevenue
Group By AcademicFiscalYr
        ,TuitionCampus

--5.a2: The calibration factor is calculated as actual collections divided by uncalibrated revenue by campus. 
----Actual operating fee collections by campus can be found in the table, OPB_ActualCollections


Select n.AcademicFiscalYr
      ,n.TuitionCampus
      ,a.ActualOperatingFeeCollectionsAmt/n.UNet  As CF
Into #CalibrationFactor
From #NetByCampus n
Inner Join AnalyticInteg.sec.OPB_ActualCollections a
  On  a.AcademicFiscalYr = n.AcademicFiscalYr
  And a.TuitionCampus = n.TuitionCampus
Where n.Unet>0 
  And a.ActualOperatingFeeCollectionsAmt>0


--5.a3: Apply Calibration Factor: GrossOp, GrossROp, and the OpWvr values are each multiplied by the calibration factor. 
----It is assumed that the same calibration factor can be applied to each quarter. While this assumption may not be quite accurate, 
----doing so enables us to provide net revenue information by academic quarter for those who need it.

Select u.AcademicFiscalYr
      ,u.AcademicQtrKeyId
      ,u.TuitionCampus
      ,u.TuitionGroup
      ,u.TuitionGroupName
      ,u.TGsort
      ,u.TuitionCategory
      ,u.TuitionCategoryName
      ,u.TuitionResidency
      ,u.TuitionResidencyName
      ,u.StdtLvl
      ,cast(u.AnnualHeadcount as decimal (6,0)) As AnnualHC
      ,cast(u.QtrHeadcount as decimal (6,0)) as QtrHC
      ,cast(u.AnnualFTE as decimal (6,0)) as AnnualFTE
      ,cast(u.QtrFTE as decimal (6,0)) as QtrFTE
      ,c.CF*u.GrossOpFeeRevenue As GrossOp
      ,c.CF*u.GrossResOpFeeRevenue As GrossResOp
      ,c.CF*u.OpWvr  As OpWvr
      ,c.CF*u.ResWvr As ResWvr
      ,c.CF*u.AnyWvr as AnyWvr
      ,c.CF*u.NRDWvr as NRDWvr
Into #CalibratedNetRevenueS1
From #UncalibratedNetRevenue u
Inner Join #CalibrationFactor c 
  On  c.AcademicFiscalYr = u.AcademicFiscalYr 
  And c.TuitionCampus = u.TuitionCampus


--5.b: Subtraction of UW Set-Aside and additional aid. The inclusion of 1% UW Set-Aside is explained above at the beginning of Step 5. 
----In addition, as explained in ABB documentation, there are "additional aid pools" that are subtracted from net revenue prior to distribution. Currently, there are two pools. 
----The first is a pool of aid for resident undergrads that is taken from undergraduate revenue. It was first created by legislative requirement in 2009-10, the first recent 
----year in which the UW experienced double-digit tuition increases. As tuition has increased further, the pool has increased each year. The precise portion of incremental 
----revenue that has been added was approved by the Regents each year, but the rationale behind the specific annual calculation has varied from year to year. 
----For Seattle domestic non-residents, another additional pool was created in FY14 to help attract domestic nonresidents.

----The calculations of the Need/Merit pool, Set-Aside, and net revenue are done first, as in Step 3. Then the additional aid pools are subtracted to get the FinalNetRevenue. 
----The values for the additional aid pools can be found in OPB_AdditionalAidPool. 
----The final temporary table created, which provides calibrated net revenue by year, campus, and tuition group, is ##CalibratedNetRevByTG.

--Step 5.b.1 Calculate NetOp (before additional aid)

Select
       AcademicFiscalYr
      ,AcademicQtrKeyId
      ,TuitionCampus
      ,TuitionGroup
      ,TuitionGroupName
      ,TGsort
      ,TuitionCategory
      ,TuitionCategoryName
      ,TuitionResidency
      ,TuitionResidencyName
      ,StdtLvl
      ,AnnualHC
      ,AnnualFTE
      ,GrossOp
      ,GrossResOp
      ,OpWvr
      ,AnyWvr
      ,ResWvr
      ,NRDWvr
      ,.04*GrossResOp As NMPool
      ,Case 
         when AcademicFiscalYr>=2017 then .04*(GrossOp-OpWvr-.04*GrossResOp) 
         when AcademicFiscalYr<2017 then .05*(GrossOp-OpWvr-.04*GrossResOp) 
       End As LegSetAside
-- Even though for purposes of calibration we use 4% for the set-aside beginning in FY17, it should be noted that for aid purposes, we now take out 4% for legislated set and 1% for "UWSetAside".
      ,Case when AcademicFiscalYr>=2017 then .01*(GrossOp-OpWvr-.04*GrossResOp) Else 0 End As UWSetAside 
      ,GrossOp - OpWvr - .04*GrossResOp 
        -(Case 
           when AcademicFiscalYr>=2017 then .04*(GrossOp-OpWvr-.04*GrossResOp) 
           when AcademicFiscalYr<2017 then .05*(GrossOp-OpWvr-.04*GrossResOp) 
          End)
        -(Case when AcademicFiscalYr>=2017 then .01*(GrossOp-OpWvr-.04*GrossResOp) Else 0 End) As NetOpB4Addl
   
Into #CalibratedNetRevenueS2
From #CalibratedNetRevenueS1 

--Step 5.b.2 In this step, we sum over quarter to achieve the same granularity as found in the additional aid pool table.

Select
       AcademicFiscalYr
      ,TuitionCampus
      ,TuitionGroup
      ,TuitionGroupName
      ,TGsort
      ,TuitionCategory
      ,TuitionCategoryName
      ,TuitionResidency
      ,TuitionResidencyName
      ,StdtLvl
      ,SUM(AnnualHC) as HC
      ,SUM(AnnualFTE) as FTE
      ,SUM(GrossOp) as GOp
      ,SUM(GrossResOp) as GROp
      ,SUM(OpWvr) as OpWvr
      ,SUM(AnyWvr) as AnyWvr
      ,SUM(ResWvr) as ResWvr
      ,SUM(NRDWvr) as NRDWvr
      ,SUM(NMPool) as NMPool
      ,SUM(LegSetAside) as LegSetAside
      ,SUM(UWSetAside) as UWSetAside
      ,SUM(NetOpB4Addl) as NetOpB4Addl
   
Into #CalibratedNetRevenueS3
From #CalibratedNetRevenueS2 

Group by
       AcademicFiscalYr
      ,TuitionCampus
      ,TuitionGroup
      ,TuitionGroupName
      ,TGsort
      ,TuitionCategory
      ,TuitionCategoryName
      ,TuitionResidency
      ,TuitionResidencyName
      ,StdtLvl

--Step 5.b.3 - Subtract additional aid pool

Select
       n.AcademicFiscalYr
      ,n.TuitionCampus
      ,n.TuitionGroup
      ,n.TuitionGroupName
      ,n.TGsort
      ,n.TuitionCategory
      ,n.TuitionCategoryName
      ,n.TuitionResidency
      ,n.TuitionResidencyName
      ,n.StdtLvl
      ,n.HC
      ,n.FTE
      ,n.GOp
      ,n.GROp
      ,n.OpWvr
      ,n.AnyWvr
      ,n.ResWvr
      ,n.NRDWvr
      ,n.NMPool
      ,n.LegSetAside
      ,n.UWSetAside
      ,n.NetOpB4Addl
      ,ISNULL(a.AdditionalAidPoolAmt,0) as AddlAid
      ,n.NetOpB4Addl-ISNULL(a.AdditionalAidPoolAmt,0) as NetOp
Into #CalibratedNetRevenueS4
From #CalibratedNetRevenueS3 n
Left Join AnalyticInteg.sec.OPB_AdditionalAidPool a
  On  a.AcademicFiscalYr=n.AcademicFiscalYr 
  And a.TuitionCampus=n.TuitionCampus 
  And a.TuitionCategory=n.TuitionCategory
  And a.TuitionResidency=n.TuitionResidency

--Step 5.b.4 - separate out Bothell's portion of PharmD/BothellMBA revenue.
----When the PharmD/BothellMBA program was created, it was agreed that half of the revenue from these students (in their 2nd and 3rd years) 
----would be transferred to Bothell, and half would remain at Seattle and run through ABB calculations.

Select
       AcademicFiscalYr
      ,TuitionCampus
      ,TuitionCategory
      ,TuitionCategoryName
      ,TuitionGroup
      ,TuitionGroupName
      ,TuitionResidency
      ,TuitionResidencyName
      ,Case when AcademicFiscalYr>=2017 then HC/2 Else 0 End as HC
      ,Case when AcademicFiscalYr>=2017 then FTE/2 Else 0 End as FTE
      ,Case when AcademicFiscalYr>=2017 then GOp/2 Else 0 End as GOp
      ,Case when AcademicFiscalYr>=2017 then GROp/2 Else 0 End as GROp
      ,Case when AcademicFiscalYr>=2017 then OpWvr/2 Else 0 End as OpWvr
      ,Case when AcademicFiscalYr>=2017 then AnyWvr/2 Else 0 End as AnyWvr
      ,Case when AcademicFiscalYr>=2017 then ResWvr/2 Else 0 End as ResWvr
      ,Case when AcademicFiscalYr>=2017 then NRDWvr/2 Else 0 End as NRDWvr
      ,Case when AcademicFiscalYr>=2017 then NMPool/2 Else 0 End as NMPool
      ,Case when AcademicFiscalYr>=2017 then LegSetAside/2 Else 0 End as LegSetAside
      ,Case when AcademicFiscalYr>=2017 then UWSetAside/2 Else 0 End as UWSetAside
      ,Case when AcademicFiscalYr>=2017 then NetOpB4Addl/2 Else 0 End as NetOpB4Addl
      ,Case when AcademicFiscalYr>=2017 then AddlAid/2 Else 0 End as AddlAid
      ,Case when AcademicFiscalYr>=2017 then NetOp/2 Else 0 End as NetOp
Into #PharmDBothellMBA
From #CalibratedNetRevenueS4
Where TuitionCampus=0 and TuitionCategory=87

--Step 5.b.5 - Here we subtract off Bothell's portion of PharmD/BothellMBA tuition and aggregate to tuition group

Select 
     
     convert(varchar(1),r.TuitionCampus)+'_'+Right('00'+convert(varchar(3),r.TuitionCategory),3)+'_'+convert(varchar(1),r.TuitionResidency) As StdtGp
    ,r.TuitionCampus
    ,r.TuitionGroup
    ,r.TuitionCategory
    ,r.TuitionResidency
    ,r.TuitionCategoryName
    ,r.TuitionGroupName
    ,r.TuitionResidencyName
    ,r.TGsort
    ,r.StdtLvl
    ,SUM(r.HC-ISNULL(p.HC,0)) as HC0
    ,SUM(r.FTE-ISNULL(p.FTE,0)) as FTE0
    ,SUM(r.GOp-ISNULL(p.GOp,0)) as GOp0
    ,SUM(r.GROp-ISNULL(p.GROp,0)) as GROp0
    ,SUM(r.OpWvr-ISNULL(p.OpWvr,0)) As OpWvr0
    ,SUM(r.AnyWvr-ISNULL(p.AnyWvr,0)) As AnyWvr0
    ,SUM(r.ResWvr-ISNULL(p.ResWvr,0)) As ResWvr0
    ,SUM(r.NRDWvr-ISNULL(p.NRDWvr,0)) As NRDWvr0
    ,SUM(r.NMPool-ISNULL(p.NMPool,0)) as NMPool0
    ,SUM(r.LegSetAside-ISNULL(p.LegSetAside,0)) As LegSetAside0
    ,SUM(r.UWSetAside-ISNULL(p.UWSetAside,0)) as UWSetAside0
    ,SUM(r.NetOpB4Addl-ISNULL(p.NetOpB4Addl,0)) as NetOpB4Addl0
    ,SUM(r.AddlAid-ISNULL(p.AddlAid,0)) as AddlAid0
    ,SUM(r.NetOp-ISNULL(p.NetOp,0)) As NetOp0

From #CalibratedNetRevenueS4 r
Left Join #PharmDBothellMBA p
  On r.AcademicFiscalYr=p.AcademicFiscalYr and
     r.TuitionCampus=p.TuitionCampus and
     r.TuitionCategory=p.TuitionCategory and
     r.TuitionResidency=p.TuitionResidency
Group by

     convert(varchar(1),r.TuitionCampus)+'_'+Right('00'+convert(varchar(3),r.TuitionCategory),3)+'_'+convert(varchar(1),r.TuitionResidency) 
    ,r.TuitionCampus
    ,r.TuitionGroup
    ,r.TuitionCategory
    ,r.TuitionResidency
    ,r.TuitionCategoryName
    ,r.TuitionGroupName
    ,r.TuitionResidencyName
    ,r.TGsort
    ,r.StdtLvl
Order by
    convert(varchar(1),r.TuitionCampus)+'_'+Right('00'+convert(varchar(3),r.TuitionCategory),3)+'_'+convert(varchar(1),r.TuitionResidency)





